// AS3 Easing Image Slider
// Timothy Stepp - DesignWorks Group
 
import fl.transitions.*;
import fl.transitions.easing.*;
 
// Tweensy is required for this all to work. Link is on the blog page.
import com.flashdynamix.motion.Tweensy;
 
 
stop();
 
 
/*
Create min and max values for the x-position of the image.
 
Minimum value (image moves left):
The minimum x-position is determined by subtracting the stage width from the image width.
This value is then multiplied by -1 since the left movement is a negative x-direction.
If you are trying to avoid having the image shift too far to the left, you cannot have the image
position itself at an x-value that exposes the canvas behind your image. 
 
Maximum value (image moves right):
The maximum x-value is zero because if the image moves any further right, the canvas behind 
the image, on the left side will be exposed.
 
*/
var minX:Number = ( - ( pan.width - stage.stageWidth ) );
var maxX:Number = 0;
 
 
/*
Create minimum and maximum values for time length of each tween.
*/
var minTime:Number = 20;
var maxTime:Number = 23;
 
/*
Create minSlide variable
 
The minSlide variable defines the minimum change of each sliding occurance. This is necessary 
to maintain a smooth presentation. If a random number is generated and happens to be five pixels
away from the current X position, think about how unfitting a ten second tween would look - the
image would move only a centimeter in ten seconds.
*/
var minSlide:Number = 200;
 
// Run first tween.
createTween( );
 
 
function createTween():void{
	Tweensy.to( pan, { x:randomX( ) }, randomNumber( minTime, maxTime ), Strong.easeOut, 0, null, newTween );
}
 
function newTween( ):void {
	createTween( );
}
 
 
/*
Generate the function that produces a random number within your scope and that respects the
minSlide variable
*/
 
function randomX( ):Number{
	// Check if current x is too far right
	if( currentX( ) > maxX ){
		trace( "X-position exceeded maximum bound" );
	}
 
	// Check if current x is too far left
	else if ( currentX( ) < minX ){
		trace( "X-position exceeded minimum bound" );
	}
 
	/*
	In order to respect the minSlide variable, create two statements that
	guide the pan element accordingly if the current x-position is too close to the left or right.
	*/
	else if( ( currentX( ) - minX ) < minSlide ){
		return randomNumber( ( currentX( ) + minSlide ), maxX );
	}
 
	else if( ( maxX - currentX( ) ) < minSlide ){
		return randomNumber( minX, ( currentX( ) - minSlide ) );
	}
 
	/*
	If the x-position is not within +/- minSlide away from minX and maxX, it is in the middle area.
	A switch randomly chooses to pitch the pan left or right.
	*/
	else if ( currentX( ) >= ( minX + minSlide ) && currentX( ) <= ( maxX - minSlide ) ){
		switch( Math.round( Math.random( ) ) ){
			case 0: return randomNumber( minX, ( currentX( ) - minSlide ) );
			case 1: return randomNumber( ( currentX( ) + minSlide ), maxX  );
		}
	}
 
	else {
		trace( "There was an unexplained error" );
	}
 
	trace( "Error: returning zero" );
	return 0;
}
 
function currentX( ):Number {
	return this.pan.x;
}
 
/*
Function for generating a random number
*/  
function randomNumber( low:Number = NaN, high:Number = NaN ):Number{
	var low:Number = low;
  	var high:Number = high;
 
  	if( isNaN( low ) ){
    	throw new Error( "low must be defined" );
  	}
 
  	if( isNaN( high ) ){
		throw new Error( "high must be defined" );
  	}
 
  	return Math.round( Math.random( ) * ( high - low ) ) + low;
}